cmake_minimum_required (VERSION 3.28 FATAL_ERROR)

# KDE Application Version, managed by release script
set (RELEASE_SERVICE_VERSION_MAJOR "25")
set (RELEASE_SERVICE_VERSION_MINOR "11")
set (RELEASE_SERVICE_VERSION_MICRO "80")
set (RELEASE_SERVICE_VERSION "${RELEASE_SERVICE_VERSION_MAJOR}.${RELEASE_SERVICE_VERSION_MINOR}.${RELEASE_SERVICE_VERSION_MICRO}")

set(CMAKE_CXX_STANDARD 20)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

project(Kamoso VERSION ${RELEASE_SERVICE_VERSION})

set(KF6_MIN_VERSION 6.0.0)

find_package(ECM ${KF6_MIN_VERSION} REQUIRED NO_MODULE)
set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH}  ${CMAKE_CURRENT_SOURCE_DIR}/cmake)

include(KDECompilerSettings NO_POLICY_SCOPE)
include(KDEInstallDirs)
include(KDECMakeSettings)
include(ECMInstallIcons)
include(ECMAddTests)
include(FeatureSummary)
include(ECMSetupVersion)

option(BUILD_DOC "Whether to build the documentation" ON)

find_package(Qt6 NO_MODULE REQUIRED COMPONENTS Core Gui Widgets Quick)
find_package(KF6 ${KF6_MIN_VERSION} REQUIRED COMPONENTS Config KIO I18n Purpose Notifications)

if (BUILD_DOC)
    find_package(KF6DocTools ${KF6_MIN_VERSION})
    set_package_properties(KF6DocTools PROPERTIES DESCRIPTION
        "Tools to generate documentation"
        TYPE REQUIRED
    )
endif()

option(PATCHED_GSTREAMER "GStreamer includes https://gitlab.freedesktop.org/gstreamer/gstreamer/-/merge_requests/9085" OFF)
if (NOT PATCHED_GSTREAMER)
    set(GSTREAMER_MIN_VERSION "1.26.3")
else()
    set(GSTREAMER_MIN_VERSION "1.22")
endif()

find_package(PkgConfig REQUIRED)
pkg_check_modules(GStreamer IMPORTED_TARGET gstreamer-1.0>=${GSTREAMER_MIN_VERSION})
pkg_check_modules(GStreamerVideo IMPORTED_TARGET gstreamer-video-1.0)

include(ECMFindQmlModule)

ecm_find_qmlmodule(org.kde.purpose 1.0)
ecm_find_qmlmodule(org.kde.kirigami 1.0)
find_package(KF6KirigamiAddons 1.10.0 REQUIRED)

add_definitions(-DQT_NO_URL_CAST_FROM_STRING)

add_subdirectory(src)
add_subdirectory(icons)

if (BUILD_DOC)
    add_subdirectory(doc)
    kdoctools_install(po)
endif()
ki18n_install(po)

install(FILES org.kde.kamoso.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR})

feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)
